gmacro
note
note   Unverfälschter (unbiased) Test bei der Poissonverteilung: 
note     X ~ Po(lambda)
note     H0: lambda = lambda0
note     H1: lambda /= lambda0
note
note   hier: Gütefunktion punktweise berechnen
note         bei gegebenem kl, deltal, kr, deltar
note
note   Eingabe:  K4 = kl = linker kritischer Wert
note             K5 = kr = rechter kritischer Wert
note             K6 = deltal
note             K7 = deltar
note             C1: Werte von lambda, für welche die Gütefunktion
note                 berechnet werden soll
note
name  k4 'kl' k5 'kr' k6 'deltal' k7 'deltar'
print k4-k7
note Sind die Eingabewerte in Ordnung und ist die Spalte C1 vorbestzt (y/n)?
yesno k10
if k10=0
  exit
endif

erase c2-c4
name  k9 'i' k10 'lambda_i' k20 'beta(lambda_i)' c1 'lambda' c2 'beta(lambda)' 

# Gütefunktion berechnen für lambda-Werte in C1
let k21 = count(c1)
do 'i'=1 : k21
  let 'lambda_i'=c1(i)
  # Berechnung der Gütefunktion beim aktuellen Wert von lambda:
  PDF 'kl' k11;
    Poisson 'lambda_i'.
  PDF 'kr' k12;
    Poisson 'lambda_i'.
  let k17 = 'kl'-1
  CDF k17 k18;
    Poisson 'lambda_i'.  # k18 = Pr{X < kl}
  CDF 'kr' k19;
    Poisson 'lambda_i'.
  let k19 = 1-k19       # k19 = Pr{X > kr}
  let 'beta(lambda_i)' = k18 + k19 + 'deltal'*k11 + 'deltar'*k12
  let c2('i')='beta(lambda_i)'
enddo
endmacro