gmacro
note
note
note  Simulation zum Würfelexperiment zur Bestimmung der
note  Ablehnwahrscheinlihckeit (Gütefunktion) bei einem
note  gefälschten Würfel: 
note  
note  Eingabe: K1 = M = Anzahl der Simulationen (Versuche)
note           K2 = n = Anzahl der Würfe in einem Versuch
note           C1 = Augenzahlen 1 bis 6
note           C2 = Wahrscheinlichkeiten beim gefälschten Würfel
note           C3 = Wahrscheinlichkeiten beim idealen Würfel
note
note  Ausgabe: C9 = Werte der Chi-Quadrat-Testgröße bei den M Simulationen

# 'i'    (=k3) = Nummer der jeweiligen Stichprobe (i=1,...,M)
# C4:    Erwartete Häufigkeiten unter Ho (idealer Würfel)
# C5:    Würfelergebnisse bei der jeweiligen Simulation
# C6,C7: Häufigkeitstabelle zur jeweiligen Simulation
# C8:    Summanden der Chi-Quadrat-Testgröße bei der jeweiligen Simulation
# C9(i)= Wert der Chi-Quadrat-Testgröße bei der i-ten Simulation

name k1 'mm'
name k2 'n'
name c1 'j'
name c2 'theta_j'
name c3 'theta0_j'
print k1-k2 
note Sind die Eingabewerte in Ordnung (y/n)?
yesno k10
if k10=0
  exit
endif

name k3 'i'
name c4 'e_j'
name c7 'n_j' 
name c9 'chi^2-TG'
brief 0
let 'e_j'='n'*'theta0_j'
do 'i'=1 : 'mm'
  Random 'n' c5;
    Discrete c1 c2.
  tally c5;
    counts;
    store c6-c7.
  let c8=(c7-c4)**2/c4
  let c9('i')=sum(c8)
enddo
brief 2
endmacro