GMACRO
n_binom
note
note Notwendiger Stichprobenumfang beim Binomialtest:
note (vgl. Uebungsaufgabe 51)
note 
note Testproblem: H_0: theta <= theta_0  gegen  H_1: theta > theta_0
note
note Eingabe:    
note   theta_0:             theoretischer Vergleichsparameter
note   theta_1 (> theta_0): Wert im Bereich der Alternative
note   alpha:               Signifikanzniveau des einseitigen Tests
note   n = Stichprobenumfang  
note 
let k5=0  # Variable zu yesno vorbesetzen
while k5=0
  note Einlesen von theta_0, theta_1, alpha:
  set c1;
  file 'terminal';
  nobs 3.
  let k1=c1(1)
  let k2=c1(2)
  let k3=c1(3)
  name k1 'theta_0'
  name k2 'theta_1'
  name k3 'alpha'
  print k1-k3
  note
  note Sind die Eingabewerte in Ordnung (y/n)?
  yesno k5
endwhile
let k5=0 # Variable zu yesno wieder vorbesetzen
while k5 = 0 
  note
  note Eingabe des Stichprobenumfangs n:
  set c1;
  file 'terminal';
  nobs 1.
  let k4=c1(1)
  name k4 'n'
  # Berechnung der rechten kritischen alpha-Schranke zu Bi(n,theta_0):
    let k7=1-'alpha'
    name k8 'k_r'
    InvCDF k7 'k_r';
    Binomial 'n' 'theta_0'.
  # Gütefunktion im Punkt theta_0 = Pr{X > kr} = 1-Pr{X <= kr} --->  K9
    CDF 'k_r' k9;
    Binomial 'n' 'theta_0'.
    let k9=1-k9
    name k9 'beta(theta_0)'
  # Gütefunktion im Punkt theta_1 = Pr{X > kr} = 1-Pr{X <= kr} --->  K10
    CDF 'k_r' k10;
    Binomial 'n' 'theta_1'.
    let k10=1-k10
    name k10 'beta(theta_1)'
  print k1-k4 k8 k9 k10
endwhile
ENDMACRO