gmacro
aufg61   # Name des Makros"
# Simulation zum Würfelexperiment: 
# Ablehnwahrscheinlichkeit beim Chi-Quadrat-Test

# C1 = 'j'      = mögliche Würfelergebnisse (vorbesetzen: 1-6)
# C2 = 'thetaj' = tatsächliche W'keiten (vorbesetzen)
# C3 = 'ej'     = erwartete Häufigkeiten unter H0 (vorbesetzen)
# 'mm' (=k1) = Gesamtzahl M der Simulationen (vorbesetzen)
# 'n'  (=k2) = Stichprobenumfang n (vorbesetzen)

# 'i'  (=k3) = Nummer der jeweiligen Stichprobe (i=1,...,M)
# C4:    Würfelergebnisse bei der jeweiligen Simulation
# C5,C6: Häufigkeitstabelle zur jeweiligen Simulation
# C7:    Summanden der Chi-Quadrat-Testgröße bei der jeweiligen Simulation
# C8(i)= Wert der Chi-Quadrat-Testgröße bei der i-ten Simulation

name k1 'mm'
name k2 'n'
name k3 'i'
name c1 'j'
name c2 'theta_j'
name c3 'ej'
name c8 'chi^2-TG'
brief 1
let k5=sum(c2)
let k6=sum(c3)
if k5 ne 1 or k6 ne 'n'
  note  
  note   Eingabedaten in Spalte 2 oder 3 nicht korrekt!
  note
  exit
endif
brief 0
do 'i'=1 : 'mm'
  Random 'n' c4;
    Discrete c1 c2.
  tally c4;
    counts;
    store c5-c6.
  let c7=(c6-c3)**2/c3
  let c8('i')=sum(c7)
enddo
brief 2
endmacro