MACRO
kendall n xv yv
# n = Länge der beiden Spalten xv und yv
# xv, yv: Spalten mit den x- und y-Werten
#
# Dieses Makro berechnet zu den beiden Spaltenvektoren xv und yv 
# den Korrelationkoeffizienten r von Kendall:
#        Q+ - Q-
#   r = --------- 
#        Q+ + Q-
# wobei
#   Q+ = Anzahl der konkordanten Paare
#   Q- = Anzahl der diskorddanten Paare
#   (Q0= Anzahl der Paare, die weder kon- noch diskordant sind)
#
MCONSTANT n nmin1 Qplus Qminus Qnull Kendall i j j0 j1 
MCOLUMN   xv yv x y
sort xv yv x y;  # Ordnen nach Groesse der x-Werte!
  by xv.
let Qplus  = 0
let Qminus = 0
let Qnull  = 0
let nmin1  = n-1
do i = 1 : nmin1
  let j0 = i+1
  let j1 = n+1
  do j = j0 : n
    if x(i) < x(j)
      let j1 = j
      break
    endif
    let Qnull = Qnull+1       # x(i)=x(j)
  enddo
  if j1 = n+1
    next
  endif
  do j = j1 : n
    if y(i) < y(j)
      let Qplus =  Qplus+1    # x(i)<x(j) und y(i)<y(j)
    elseif y(i) > y(j)
      let Qminus =  Qminus+1  # x(i)<x(j) und y(i)>y(j)
    else
      let Qnull = Qnull+1     # y(i)=y(j)
    endif      
  enddo
enddo
let kendall = (Qplus-Qminus)/(Qplus+Qminus)
print Qplus Qminus Qnull Kendall
ENDMACRO